CMAKE入门（二）

第三步、增加库的使用要求

使用要求（usage requirements）允许更好地控制库或可执行程序的链接和include头文件，同时也给予了对CMake内部目标传递属性的更多控制。

关于使用要求的命令有四个：

target_compile_definitions()

target_compile_options()

target_include_directories()

target_link_libraries()

让我们重构从添加一个库(步骤2)开始的代码，把使用要求加入CMake代码中。

我们首先声明，任何链接到MathFunctions的人都需要包含当前的源目录，而MathFunctions本身不需要。因此，这可以成为一个接口使用需求。

记住，接口意味着消费者需要而生产者不需要的东西。在MathFunctions/CMakeLists.txt的末尾添加以下几行:

target_include_directories(MathFunctions
          INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}
          )

现在我们已经指定了MathFunctions的使用要求，我们可以安全地从顶级的cmakellists .txt中删除EXTRA_INCLUDES变量的使用，这里:

if(USE_MYMATH)
  add_subdirectory(MathFunctions)
  list(APPEND EXTRA_LIBS MathFunctions)
endif()

还有这里：

target_include_directories(Tutorial PUBLIC
                           "${PROJECT_BINARY_DIR}"
                           )

一旦这是完成，运行cmake可执行文件或cmake-gui配置项目，然后从构建目录构建它与您选择的构建工具或使用cmake-build。

第四步、安装与测试

现在我们可以开始向项目添加安装规则和测试支持了。

安装规则

安装规则十分的简单：对于MathFunctions，我们希望安装库文件和头文件，而对于应用程序，我们希望安装可执行和配置的头文件。

所以在MathFunctions/CMakeLists.txt的末尾添加:

install(TARGETS MathFunctions DESTINATION lib)
install(FILES MathFunctions.h DESTINATION include)

然后在顶层CMakeLists.txt的末尾添加:

install(TARGETS Tutorial DESTINATION bin)
install(FILES "${PROJECT_BINARY_DIR}/TutorialConfig.h"
  DESTINATION include
  )

这就是创建本教程的基本本地安装所需的全部内容。

现在运行cmake可执行文件或cmake-gui来配置项目，然后使用所选的构建工具构建它。

然后使用cmake命令的install选项运行安装步骤。对于多配置工具，不要忘记使用——config参数来指定配置。如果使用IDE，只需构建INSTALL目标。此步骤将安装适当的头文件、库和可执行文件。例如:

cmake --install .

CMake变量CMAKE_INSTALL_PREFIX用于确定将安装文件的根目录。如果使用cmake——install命令，安装前缀可以通过——prefix参数覆盖。例如:

cmake --install . --prefix "/home/myuser/installdir"

导航到安装目录并验证已安装的教程是否运行。

测试支持

接下来让我们测试我们的应用程序。在顶级CMakeLists.txt文件的末尾，我们可以启用测试，然后添加一些基本测试，以验证应用程序是否正常工作。

enable_testing()

# does the application run
add_test(NAME Runs COMMAND Tutorial 25)

# does the usage message work?
add_test(NAME Usage COMMAND Tutorial)
set_tests_properties(Usage
  PROPERTIES PASS_REGULAR_EXPRESSION "Usage:.*number"
  )

# define a function to simplify adding tests
function(do_test target arg result)
  add_test(NAME Comp${arg} COMMAND ${target} ${arg})
  set_tests_properties(Comp${arg}
    PROPERTIES PASS_REGULAR_EXPRESSION ${result}
    )
endfunction(do_test)

# do a bunch of result based tests
do_test(Tutorial 4 "4 is 2")
do_test(Tutorial 9 "9 is 3")
do_test(Tutorial 5 "5 is 2.236")
do_test(Tutorial 7 "7 is 2.645")
do_test(Tutorial 25 "25 is 5")
do_test(Tutorial -25 "-25 is [-nan|nan|0]")
do_test(Tutorial 0.0001 "0.0001 is 0.01")

第一个测试只是验证应用程序运行，没有段错误或崩溃，并且返回值为零。这是CTest测试的基本形式。

下一个测试使用PASS_REGULAR_EXPRESSION测试属性来验证测试的输出是否包含某些字符串。在本例中，验证当提供了不正确数量的参数时，会打印usage消息。

最后，我们有一个名为do_test的函数，它运行应用程序并验证计算的平方根对于给定的输入是否正确。对于do_test的每次调用，将向项目添加另一个测试，该测试具有基于传递的参数的名称、输入和预期结果。

重建应用程序，然后cd到二进制目录，并运行ctest可执行文件:ctest -N和ctest -VV。对于多配置生成器(例如Visual Studio)，必须指定配置类型。例如，要在Debug模式下运行测试，请从构建目录(而不是Debug子目录!)使用ctest -C Debug -VV。或者，从IDE构建RUN_TESTS目标。